Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Chapter 1 - Utilidades o librerías integradas
Section 0 - Cosas comunes a usar
[Hack ofrecido por Eliuk]
Include (-
[ InitAcceleration addr res;
@gestalt 9 0 res;
if (res == 0) { return; }
addr = #classes_table;
@accelparam 0 addr;
@accelparam 1 INDIV_PROP_START;
@accelparam 2 Class;
@accelparam 3 Object;
@accelparam 4 Routine;
@accelparam 5 String;
addr = #globals_array + WORDSIZE * #g$self;
@accelparam 6 addr;
@accelparam 7 NUM_ATTR_BYTES;
addr = #cpv__start;
@accelparam 8 addr;
@accelfunc 1 Z__Region;
@accelfunc 2 CP__Tab;
@accelfunc 3 RA__Pr;
@accelfunc 4 RL__Pr;
@accelfunc 5 OC__Cl;
@accelfunc 6 RV__Pr;
@accelfunc 7 OP__Pr;
];
-)
To enable veneer acceleration:
(- InitAcceleration(); -)
[Substancias, al menos para considerar lo metálico ]
Substancia is a kind of value. The substancias are metal, flint, green, meat, paper and irrelevante.
A thing has a substancia called naturaleza. The naturaleza of a thing is usually irrelevante.
Definition: a thing is metalica if the naturaleza of it is metal.
Definition: a thing is chisposa if the naturaleza of it is flint.
Definition: a thing is carne if the naturaleza of it is meat.
Definition: a thing is vegetal if the naturaleza of it is green.
Definition: a thing is papel if the naturaleza of it is paper.
[Volumen]
Volumen is a kind of value. The volumens are minusculo, pequeno, medio, grande and enorme.
A thing has a volumen called tamano. The tamano of a thing is usually pequeno.
To decide which number is espacio de (item - a thing):
if the tamano of item is:
-- minusculo: decide on 1;
-- pequeno: decide on 10;
-- medio: decide on 30;
-- grande: decide on 200;
-- enorme: decide on 1000.
[Capacidad]
A container has a number called capacidad. The capacidad of a container is normally 50. [objetos minusculos]
[Carga del jugador]
To decide which number is carga del jugador:
let carga be 0;
repeat with item running through the things carried by the player:
increase carga by espacio de item;
decide on carga.
[Contenido de un contenedor]
To decide which number is carga de (item - a thing):
let carga be 0;
repeat with cosa running through the things in item:
increase carga by espacio de cosa;
decide on carga.
[Como va de cargado el deavork]
To decide which number is carga del insecto:
let carga be 0;
repeat with cosa running through the things in estomago del deavork:
increase carga by espacio de cosa;
decide on carga.
[Verificar la carga del jugador]
Before taking a thing:
let carga final be carga del jugador;
increase carga final by espacio de the noun;
let maxCarga be 235;
if the player is icalante or the player is yerk:
change maxCarga to 435;
if carga final is greater than maxCarga:
if the player is carrying anything:
say "Tu portador ya lleva demasiadas cosas, tendrás que dejar algo antes de cargar con [the noun].";
otherwise:
say "Simplemente tu portador no puede cargar con eso, es demasiado grande.";
stop the action.
[Verificar capacidad de un contenedor]
Before inserting a thing into a open container:
let carga final be carga de the second noun;
increase carga final by espacio de the noun;
if carga final is greater than capacidad of the second noun:
if there is anything in the second noun:
say "[The noun] ya no cabe en [the second noun]. Saca algo antes.";
otherwise:
say "[The noun] parece que simplemente no cabe ahí.";
stop the action.
[----------------------------------------------------
Algunas funciones de presentación
-----------------------------------------------------]
To bnw: [break and wait]
say line break;
[say paragraph break;]
wait for any key.